#include "colors.inc"

camera
{
  location <-14, 9, 1.2>*.45
  look_at <0, -1.5, 0>
  angle 95
  aperture .09
  blur_samples 30
  focal_point <0, 0, 0>
  variance 1/600
  confidence .98
}

sky_sphere
{
  pigment
  {
    bozo
    turbulence .9
    #declare percentRed = 55;
    color_map
    {
      [0	Orange]
      [0.7	percentRed*.01*Red+(100-percentRed)*.01*Orange]
      [1	Red]
    }
    scale .15
    translate y*1.2
  }
}

#declare a = -1.85;
#declare b = 2.85;
#declare c = 1;

/*blob
{
  threshold 0.5
  sphere { <a, 0, 0>, b, c }
  sphere { <a, 0, 0>, b, c rotate y*120 }
  sphere { <a, 0, 0>, b, c rotate y*240 }

  texture
  {
    pigment { color Gold }//rgb <.9, .9, .95> }
    finish { reflection .95 diffuse .1 ambient 0 }
  }

  rotate z*20
}*/

sphere
{ <0, 0, 0>, 3.5
  texture
  {
    pigment { color Gold }//rgb <.9, .9, .95> }
    finish { reflection .95 diffuse .1 ambient 0 }
  }
}

#declare iterations = 40;

#macro torusThing(level)
  torus { 5.03, .44 scale y*1.5 }
  #if (level > 1)
    #local it = 0;
    #while (it < iterations)
      union { torusThing(level-1)
	scale .2
	rotate z*90 
	translate z*5
	rotate y*(it/iterations)*360
      }
      #local it = it+1;
    #end
  #end
#end

union { torusThing(4)
    texture
    {
      pigment { color White }
      finish 
      { 
        diffuse .725
        ambient ((Red+Orange)/2)*.4
        specular .5 
	roughness .02 
	reflection .125
      }
      normal { wrinkles .35 scale .2 turbulence .7 }
    }
}

light_source {<-15, 10, -10>, Red area_light y, z, 3, 3 adaptive 3}
light_source {<-20, 3, 15>, Orange area_light y, z, 3, 3 adaptive 3}
light_source {<.5, 11, .3>, Orange*.75 area_light x, z, 3, 3 adaptive 3}